Blog

Asterisk: Audible Caller ID – June 06, 2009

In addition to hosting phone services for other people, I also host my own phone numbers (personal and business). I prefer to not have different phones for each line, but I like any phone to be used for either number at any given time. I haven't gotten around to setting up distinctive ringing for the different lines, but instead, our home computer audibly announces the caller's name and number, and, for the business calls, which menu choice they made.

All that needs to be done on the Asterisk side is:

The timeout and tries parameters are important, because the dialplan will hang until the wget returns. Replace <hostname> with your domain or IP of your home computer. Replace <port> with an appropriate port number (I also run a "regular" web server on port 80, so I needed to use a different port for this project).

Note, for those of you who consider security an important factor when dealing with random data from the internet, that I filter the caller ID values to try to prevent someone from attempting to hack into my computer.

Kind of crude, and perhaps there is a regular expression filter that would work better, but I looked around for a bit, and couldn't get it to work, so just went the simple route.

On the home computer side, I found code for a small perl server somewhere, and modified it for my needs, and then installed festival, to do the text to speech work.

#!/usr/bin/perl -Wall
use strict;
use warnings;
use diagnostics;
use Socket;
use IO::Select;
use threads;
use threads::shared;
$|  = 1;
local *S;
my $port_listen=<portnumber>;
socket (S, PF_INET, SOCK_STREAM,
        getprotobyname('tcp')) or die "couldn't open socket: $!";
setsockopt (S, SOL_SOCKET, SO_REUSEADDR, 1);
bind       (S, sockaddr_in($port_listen, INADDR_ANY));
listen     (S, 5)  or die "don't hear anything:  $!";
my $ss = IO::Select->new();
$ss -> add (*S);
while(1) {
    my @connections_pending = $ss->can_read();
    foreach (@connections_pending) {
        my $fh;
        my $remote = accept($fh, $_);
        my($port,$iaddr) = sockaddr_in($remote);
        my $peeraddress = inet_ntoa($iaddr);
        my $t = threads->create(\&new_connection, $fh);
    }
}
sub new_connection {
  my $fh = shift;
  binmode $fh;
  my %req;
  $req{HEADER}={};
  my $request_line;
  my $first_line = "";
  while(($request_line = <$fh>) ne "\r\n") {
      if(!$request_line){
          close $fh;
          die;
      }
      chomp $request_line;
      unless ($first_line) {
          $first_line = $request_line;
          my @parts = split(" ", $first_line);
          if(@parts != 3){
              close $fh;
              die;
          }
          $req{METHOD} = $parts[0];
          $req{OBJECT} = $parts[1];
      }
  }
  print $fh "Thanks.\n";
  close($fh);
  http_request_handler(\%req);
}
sub extract_vars {
    my $line = shift;
    my %vars;
    # need a ? for there to be valid parameters
    return \%vars if(!($line =~ s/^.*\?//));
    foreach my $part (split '&', $line) {
        $part =~ /^(.*)=(.*)$/;
        my $n = $1;
        my $v = $2;
        $n =~ s/%(..)/chr(hex($1))/eg;
        $v =~ s/%(..)/chr(hex($1))/eg;
        $vars{$n}=$v;
    }
    return \%vars;
}
sub http_request_handler{
  my $req_   =   shift;
  my %req    =   %$req_;
  my %vars = %{extract_vars($req{OBJECT})};
  if(!$vars{"number"}){
      print "no number given";
      return;
  }
  my $phonenum = $vars{"number"};
  $phonenum =~ s/[^0-9]//g;
  my $phonename = "";
  my $phoneTo = "";
  if($vars{"name"}){
      $phonename = $vars{"name"};
      $phonename =~ s/[^:a-zA-Z ]//g;
      $phonename =~ s/unknown//;
      if($phonename =~ m/^([A-Z]):/){
          $phoneTo = "Support" if($1 eq "S");
          $phoneTo = "Consulting" if($1 eq "C");
          $phoneTo = "Billing" if($1 eq "B");
          $phoneTo = "Rental" if($1 eq "R");
          $phoneTo = "" if($1 eq "H");
          $phonename =~ s/^[A-Z]://;
      }
  }
  my $spoken_string = "Call from: $phonename, $phonenum";
  if($phoneTo){
      $spoken_string = "Lime Daley $phoneTo " . $spoken_string;
  }
  print $spoken_string;
  system("echo '$spoken_string' | festival --tts");
}

Note, the "thanks" message that is returned, helps wget end quicker (and note that I print it out before I do the text to speech stuff, so if there is any trouble, or if the TTS takes a while, the dial plan won't get hosed (Hint: various bad things can happen, say, hypothetically during initial development and debugging, which causes your Asterisk server to have lots of calls hanging around and never ending, which causes various problems on the Asterisk side of things; But, I've only heard that from other people, my code always works perfectly the first time)

The only thing that isn't the best about this code is that if you are actually sitting right next to the computer, or if you are already on a call, sometimes the caller ID announcement is too loud and/or too long. But, for the most part, it is perfect, and the kids know which phone calls they are allowed to answer, and you don't have to look at the caller ID screen to see who it is.